تبدیل چند خط اندیکاتور تریدینگ ویو به متاتریدر

شرح پروژه

//@version=4
study("Trend Lines", shorttitle="TL", overlay=true)

srch = input(high, "Highs Source")
srcl = input(low, "Lows Source")
mn = input(21, "Short Range", minval=1)
F = input(5, "Long Range Factor", minval=2)
mx = min(mn * F, 300) // necessary to avoid PineScript's hardcoded iteration-limit on looped code
mn := floor(mx / F)
of = input(0, "Offset", minval=0)
mx := mx + of
mn := mn + of
nr = input(2, "Noise Reduction", minval=0)
sm = nr + 1
exp = input(false, "Use logarithmic scale")
sr = input(true, "Show Resistance (Red)")
ss = input(true, "Show Support (Green)")
sa = input(true, "Show Average (Yellow)")
rl = input(true, "Show Reference Lines")
cr = input(false, "Show Criss-cross")
tl = input(false, "Show Trace Lines")

SRCH = ema(srch, sm)
SRCL = ema(srcl, sm)

gap = 2

hhh = 0.0
lll = 1000000000000.0

mx4 = 100

h2 = hhh
th2 = 0
l2 = lll
tl2 = 0
h1 = hhh
th1 = 0
l1 = lll
tl1 = 0
for i = of to mx
    if i > mn - gap // find closest high and low
        h2 := max(h2, SRCH[i])
        if h2 == SRCH[i]
            th2 := i
        l2 := min(l2, SRCL[i])
        if l2 == SRCL[i]
            tl2 := i
    
    if i < mn + gap // find farthest high and low
        h1 := max(h1, SRCH[i])
        if h1 == SRCH[i]
            th1 := i
        l1 := min(l1, SRCL[i])
        if l1 == SRCL[i]
            tl1 := i

a1 = avg(h1, l1)
ta1 = round(avg(th1, tl1))
a2 = avg(h2, l2)
ta2 = round(avg(th2, tl2))

PLT(P1, P2, T1, T2) =>
    if exp
        t = T1 - T2
        slope = (log10(P1) - log10(P2)) / (0 - t)
        y = slope * T1 + log10(P1)
        pow(10, y)
    else
        ((P2 - P1) / (T1 - T2)) * (T2) + P2

PLC = (barstate.islast or tl) and of == 0

PLTh = PLC ? PLT(h1, h2, th1, th2) : na
PLTl = PLC ? PLT(l1, l2, tl1, tl2) : na
PLTa = PLC ? PLT(a1, a2, ta1, ta2) : na

sty =  tl ? plot.style_stepline : plot.style_circles
lin = tl ? 1 : 2 

plot(PLTh, "Res", color=#ff0088, transp=0, style=sty, linewidth=lin)
plot(PLTa, "Avg", color=#ffff00, transp=0, style=sty, linewidth=lin)
plot(PLTl, "Sup", color=#00ff88, transp=0, style=sty, linewidth=lin)

bgcolor(close > PLTh ? color.new(#ff0088, 95) : color.new(#ff0088, 100), title="Close over Resistance")
bgcolor(close < PLTl ? color.new(#00ff88, 95) : color.new(#00ff88, 100), title="Close under Support")

L(T1, H1, T2, H2, CLR, W, X) =>
    line.new(bar_index - max(T1, 0), H1, bar_index - max(T2, 0), H2, color=CLR, width=W, extend=X ? extend.both : extend.none)

if sr
    L1b = L(th1, h1, th2, h2, #ff0088, 1, true), line.delete(L1b[1])
    if rl
        L1a = L(th1, h1, th2, h2, #ff0088, 3, false), line.delete(L1a[1])
if ss
    L2b = L(tl1, l1, tl2, l2, #00ff88, 1, true), line.delete(L2b[1])
    if rl
        L2a = L(tl1, l1, tl2, l2, #00ff88, 3, false), line.delete(L2a[1])
if sa
    L3b = L(ta1, a1, ta2, a2, #ffff00, 1, true), line.delete(L3b[1])
    if rl
        L3a = L(ta1, a1, ta2, a2, #ffff00, 3, false), line.delete(L3a[1])
if cr    
    L4b = L(th1, h1, tl2, l2, #cccccc, 1, false), line.delete(L4b[1])
    L5b = L(tl1, l1, th2, h2, #cccccc, 1, false), line.delete(L5b[1])

مهارت ها و تخصص های مورد نیاز

درباره کارفرما

کاربر537583

عضویت دو سال پیش

1 پروژه ثبت شده ،

0 پروژه در حال انجام ،

0 پروژه آماده دریافت پیشنهاد ،

نرخ پذیرش پیشنهاد 100%